insect man page

insect — interactive scientific calculator

Synopsis

insect [EXPR]

Description

insect is a high-precision scientific calculator with full support for physical units.

It can be used in interactive mode by simply calling insect. This mode can also be used to read from a file, by simply piping the file contents via insect < my-calculation.ins. If you want to evaluate just a single expression, pass it as an argument: insect '70mph to km/h'.

Documentation

  • Evaluate mathematical expressions:

    1920/16*9
    2^32
    sqrt(1.4^2 + 1.5^2) * cos(pi/3)^2
    • Operators: addition (+), subtraction (-), multiplication (*, ·, ×), division (/, ÷, per), exponentiation (^, **). Full list: see Reference below.
    • Mathematical functions: abs, acos, acosh, asin, asinh, atan, atan2, atanh, ceil, cos, cosh, exp, floor, fromCelsius, fromFahrenheit, gamma, ln, log, log10, maximum, minimum, mean, round, sin, sinh, sqrt, tan, tanh, toCelsius, toFahrenheit.
    • High-precision numeric type with 30 significant digits that can handle very large (or small) exponents like 10^(10^10).
    • Exponential notation: 6.022e23.
  • Physical units: parsing and handling, including metric prefixes:

    2 min + 30 s
    40 kg * 9.8 m/s^2 * 150 cm
    sin(30°)
    • Supported units: see Reference section below.
    • Implicit conversions: 15 km/h * 30 min evaluates to 7.5 km.
    • Useful error messages:

      > 2 watts + 4 newton meter
      
      Conversion error:
        Cannot convert unit N·m (base units: kg·m²·s⁻²)
                    to unit W (base units: kg·m²·s⁻³)
  • Explicit unit conversions: the -> conversion operator (aliases: , , to):

    60 mph -> m/s
    500 km/day -> km/h
    1 mrad -> degree
    52 weeks -> days
    5 in + 2 ft -> cm
    atan(30 cm / 2 m) -> degree
    6 Mbit/s * 1.5 h -> GB
  • Variable assignments:

    Example: mass of the earth

    r = 6000km
    vol = 4/3 * pi * r^3
    density = 5 g/cm^3
    vol * density -> kg

    Example: oscillation period of a pendulum

    len = 20 cm
    2pi*sqrt(len/g0) -> ms
    • Predefined constants (type list to see them all): speed of light (c), Planck's constant (h_bar), electron mass (electronMass), elementary charge (elementaryCharge), magnetic constant (µ0), electric constant (eps0), Bohr magneton (µ_B), Avogadro's constant (N_A), Boltzmann constant (k_B), gravitational acceleration (g0), ideal gas constant (R), ...
    • Last result: you can use ans (answer) to refer to the result of the last calculation.
  • User-defined functions:

    Example: kinetic energy

    kineticEnergy(mass, speed) = 0.5 * mass * speed^2 -> kJ
    
    kineticEnergy(800 kg, 120 km/h)

    Example: barometric formula

    P0 = 1 atm
    T0 = fromCelsius(15)
    tempGradient = 0.65 K / 100 m
    
    pressure(height) = P0 * (1 - tempGradient * height / T0)^5.255 -> hPa
    
    pressure(1500 m)
  • Sums and products:

    Syntax:

    sum(<expression>, <index-variable>, <from>, <to>)
    product(<expression>, <index-variable>, <from>, <to>)

    Examples:

    # sum of the first ten squares
    sum(k^2, k, 1, 10)
    
    # the factorial of n as the product 1 × 2 × ... × n
    myFactorial(n) = product(k, k, 1, n)
  • Unicode support:

    λ = 2 × 300 µm
    ν = c/λ → GHz
  • And more: tab completion, command history (arrow keys, Ctrl+R), pretty printing, syntax highlighting, ...

Reference

  • Operators (ordered by precedence: high to low)

    OperatorSyntax
    factorial!
    square, cube, ...², ³, ⁻¹, ...
    exponentiation^, **
    multiplication (implicit)whitespace
    modulo%
    divisionper
    division/, ÷
    multiplication (explicit)*, ·, ×
    subtraction-
    addition+
    unit conversion->, , , to
    assignment=

    Note that implicit multiplication has a higher precedence than division, i.e. 50 cm / 2 m will be parsed as 50 cm / (2 m).

  • Commands

    CommandSyntax
    help texthelp, ?
    list of variableslist, ls, ll
    reset environmentreset
    clear screenclear, cls
    quit (CLI)quit, exit

FAQ

  • Why are Celsius and Fahrenheit not supported?

    Compared to the SI unit Kelvin (https://en.wikipedia.org/wiki/Kelvin) and in contrast to all other units, Celsius and Fahrenheit require an additive offset when converting into and from other temperature units. This additive offset leads to all kinds of ambiguities when performing calculations in these units. Adding two temperatures in Celsius, for example, is only meaningful if one of them is seen as an offset value (rather than an absolute temperature). Insect is primarily a scientific calculator (as opposed to a unit conversion tool) and therefore focuses on getting physical calculations right.

    Even though °C and °F are not supported as built-in units, there are helper functions to convert to and from Celsius (and Fahrenheit):

    • fromCelsius takes a scalar value that represents a temperature in Celsius and returns a corresponding temperature in Kelvin:

      > fromCelsius(0)
      
         = 273.15 K
      
      > k_B * fromCelsius(23) to meV
      
         = 25.5202 meV
    • toCelsius takes a temperature in Kelvin and returns a scalar value that represents the corresponding temperature in Celsius:

      > toCelsius(70 K)
      
         = -203.15
      
      > toCelsius(25 meV / k_B)
      
         = 16.963
  • Why is 1/2 x parsed as 1/(2x)?

    Implicit multiplication (without an explicit multiplication sign) has a higher precedence than division (see operator precedence rules). This is by design, in order to parse inputs like 50 cm / 2 m as (50 cm) / (2 m). If you meant ½ · x, write 1/2 * x.

  • What is the internal numerical precision?

    By default, Insect shows 6 significant digits in the result of the calculation. However, the internal numerical precision is much higher (30 digits).

  • How does the conversion operator work?

    The conversion operator -> attempts to convert the physical quantity on its left hand side to the unit of the expression on its right hand side. This means that you can write an arbitrary expression on the right hand side (but only the unit part will be extracted). For example:

    # simple unit conversion:
    > 120 km/h -> mph
    
      = 74.5645 mi/h
    
    # expression on the right hand side:
    > 120 m^3 -> km * m^2
    
      = 0.12 m²·km
    
    # convert x1 to the same unit as x2:
    > x1 = 50 km / h
    > x2 = 3 m/s -> x1
    
      x2 = 10.8 km/h

Author

Written by David Peter <mail@david-peter.de>.

Reporting Bugs

Please report bugs on GitHub: <https://github.com/sharkdp/insect>.

See Also

Info

insect - scientific calculator